BAT

Higiena jest bardzo ważna !

PLIK HIGIENA.BAT.

Wiedzą Państwo, że program DOS - MSAV poszukuje wirusów. Jeżeli uruchomimy ten program z parametrem /n, to w wypadku pojawienia się wirusa zostanie zwrócony kod ERRORLEVEL równy 86. Natomiast komenda CHKDSK przeprowadza analizę i test dysku. Jeżeli CHKDSK nie wykryje błędów, kod ERRORLEVEL ma wartość równą 0, jeżeli jakiś błąd zostanie wykryty, ERRORLEVEL przyjmuje wartość 255. Te dwa programy DOS są podstawą, na której zbudowano prezentowany plik wsadowy. HIGIENA.BAT sprawdza wskazany dysk, poszukując wirusów i innych nieprawidłowości. W przypadku odnalezienia znanego wirusa zostanie on unieszkodliwiony. Po zakończeniu swojej pracy program HIGIENA wyświetla końcowy raport.

@ECHO OFF
IF "%1" == "C" GOTO TAK
IF "%1" == "c" GOTO TAK
IF "%1" == "A" GOTO TAK
IF "%1" == "a" GOTO TAK
IF "%1" == "B" GOTO TAK
IF "%1" == "b" GOTO TAK
GOTO POMOC
:TAK
REM Sprawdza obecność wirusa.
CLS
ECHO.
ECHO *****************************
ECHO Pracuję ...
ECHO *****************************
ECHO.
MSAV %1: /c /n > NUL
IF ERRORLEVEL 86 GOTO JEST
CLS
ECHO.
ECHO ******************************************************
ECHO ******************* DYSK %1 ***********************
ECHO Nie znalazłem wirusa.
ECHO.
:SPRDYSK
REM Sprawdza dysk.
CHKDSK %1: > NUL
IF ERRORLEVEL 255 GOTO UWAGA
ECHO Nie wykryłem błędów na dysku.
ECHO ******************************************************
ECHO.
GOTO KONIEC
:JEST
CLS
ECHO.
ECHO ******************************************************
ECHO ******************* DYSK %1 ***********************
ECHO Znalazłem wirusa, który został unieszkodliwiony.
ECHO.
GOTO SPRDYSK
:UWAGA
ECHO Wykryłem błędy na dysku. Proszę dokonać ponownie
ECHO szczegółowego sprawdzenie za pomocą programu SCANDISK.
ECHO ******************************************************
ECHO.
GOTO KONIEC
:POMOC
CLS
ECHO.
ECHO *********************************
ECHO Proszę podać także nazwę
ECHO sprawdzanego dysku.
ECHO Na przykład:
ECHO HIGIENA A
ECHO *********************************
ECHO.
:KONIEC